If you've been stuck at home a lot lately, and think you have run out of movies to watch -- think again! Here is a list of big-budget movies you might not have seen, because they flopped (lost lots of money). Follow along as I show you how I created my interactive graphical list, or jump down to the bottom to see the finished list...

The Data

I saw this online list of 45 Of The Most Expensive Box Office Flops Ever Made. It was an interesting article, with details about why each of these movies failed and lost lots of money. But I had to do a lot of scrolling to see what all the movies were, and how many millions of $ they had lost. And I had no clue when many of the movies had been released. Therefore I decided to create my own graphical/interactive list, with just the pertinent information, and add the release dates (which I had to lookup on the web), and allows me to click each movie to find out more details.

Here's a sample of what my nice/summarized data looked like:

First Attempt

In my first attempt, I used a needle plot, where the length of the needle was the amount of $ each movie lost, and I plotted it along a time axis by the release date. I overlaid a text plot, so the name of each movie was shown at the end of the needle. And one little trick - I used the reverse option on the yaxis, so the needles were pointing down (I thought that seemed appropriate, since the values represented the amount of money lost).

It was an interesting graph, but since many of the movies were released around the same dates, many of the titles were overlapping (and therefore impossible to read).

proc sgplot data=my_data noautolegend noborder;
needle x=date y=loss_millions / lineattrs=(color=red) markers markerattrs=(color=red);
text x=date y=text_y text=title / position=right rotate=90 contributeoffsets=(ymin)
    textattrs=(color=blue size=8pt);
yaxis display=(nolabel noticks noline) reverse grid gridattrs=(pattern=dot color=gray88);
xaxis display=(nolabel);
run;

 

Refined Attempt

To avoid the overlapping text, I applied the discrete option so that each of the date values would be plotted as evenly-space discrete values along the xaxis. The movies are still arranged in the order they were released - just not proportionally spaced. But there's still a problem - can you see it in the graph below?...

proc sgplot data=my_data noautolegend noborder;
needle x=date y=loss_millions / lineattrs=(color=red) markers markerattrs=(color=red);
text x=date y=text_y text=title / position=right rotate=90 contributeoffsets=(ymin)
     textattrs=(color=blue size=8pt);
yaxis display=(nolabel noticks noline) reverse grid gridattrs=(pattern=dot color=gray88);
xaxis display=(nolabel noticks noline novalues) type=discrete;
run;

Final Version

If you've got a sharp eye, you noticed two of the movie titles overlapping(near the right-side of the graph). Although the discrete option causes each unique date value along the xaxis to be plotted separately, there happened to be two movies released on the exact same date ... therefore they were plotted on the exact same discrete xaxis value.

To get around that problem, I added a variable (called order) to the dataset, containing a unique value for each movie. Then I plotted the list by that unique value, instead of the date. I also enhanced the graph by adding mouse-over text and drilldown, using the tip= and url= options. (Click here to try out these interactive capabilities.)

data my_data; set my_data;
order=_n_;
run;

proc sgplot data=my_data noautolegend noborder;
needle x=order y=loss_millions / lineattrs=(color=red) markers markerattrs=(color=red)
     url=drill tip=(title loss_millions date);
text x=order y=text_y text=title / position=right rotate=90 contributeoffsets=(ymin)
     textattrs=(color=blue size=8pt)
     url=drill tip=(title loss_millions date);
yaxis display=(nolabel noticks noline) reverse grid gridattrs=(pattern=dot color=gray88);
xaxis display=(nolabel noticks noline novalues) type=discrete;
run;

Click the image below, to see the interactive version, with mouse-over text, and drilldown links to find out more info about each movie. (Click here to see the full SAS code used to create this graph.)

Since these movies were flops (lost lots of money), you might not have seen them ... but also since these were big-budget movies, perhaps some of them are actually pretty good (if you happen to be into their topic/genre/etc). So, if you've run out of ideas for movies to watch, perhaps you will find something in this list. 🙂

If you find a movie in this list that you like(d), and think that other people reading a graph blog might also like, please leave a note/recommendation in the comments!