Through the years: SAS Enterprise Guide versions

12

My colleague Rick Wicklin maintains a nifty chart that shows the timeline of SAS releases since Version 8. A few of you asked if I could post a similar chart for SAS Enterprise Guide. Here it is. Like Rick, I used new features in SAS 9.4 to produce this chart (in fact, I cribbed heavily from his code)...but I used SAS Enterprise Guide to run the program.

Update 25Aug2020: I've updated the graph and code in this post for the most recent versions of SAS Enterprise Guide and SAS. I also gave the chart a branding facelift, switching to the light-on-dark theme named "Raven". It's a personal preference influenced by today's trends -- but it's not economical on printer ink if you decide you want a hard copy.

EG versions through the years

You might notice that my chart is a bit busier than Rick's version. As a desktop client application that works across multiple SAS versions, we tend to issue major releases of SAS Enterprise Guide more often than we update the core engine of SAS software.

On my chart, the labels on the data points indicate the "event" that motivated the release. In some cases, we issued a new release to go with a new version of SAS (such as v1.2 with SAS 8.2). In other cases, we "remastered" a version to support more languages or another operating system (such as Microsoft Vista support with v4.1 in 2007, or the L10N release of v4.3 in 2010).

You might also notice that some of these releases happened very close together. Often, SAS R&D works on updates to multiple releases in parallel. Developers make changes to multiple versions to provide maintenance and hotfix changes (based on customer needs), while still contributing to the Next Big Version that will contain the compelling new features (based on customer wishes).

Here's the code that produced the chart:

data Releases;
  format Date DATE7.;
  input Category $8. Release $7. Date DATE9. Details $15.;
  datalines;
Ancient 1.0    01Nov1999 SAS 8.0
Ancient 1.1    01Jul2000 SAS 8.1
Ancient 1.2    01Apr2001 SAS 8.2
Ancient 1.3    01Sep2001 
Ancient 2.0    01Sep2002 
Ancient 2.05   01May2003 SAS 9.0
Ancient 2.1    01Apr2004 SAS 9.1
Ancient 3.0    01May2004 .NET rewrite
Ancient 3.02   01Feb2005 remaster/L10N
Ancient 4.1    01Mar2006 
Ancient 4.1v   01Apr2007 Vista
Ancient 4.2    01Mar2009 SAS 9.2
Ancient 4.22   01Sep2009 SAS 9.2m2
Old     4.3    01Aug2010
Old     4.305l 01Sep2010 L10N
Old     4.305r 01Jul2011 SAS 9.3
Old     5.1    01Feb2012
Old     6.1    01Jul2013 SAS 9.4
Old     7.1    01Oct2014 
Old     7.11   01May2015
Old     7.12   01Feb2016
Old     7.13   01Nov2016 SAS 9.4m4
Recent  7.15   01Sep2017 SAS 9.4m5
Recent  8.1    01Jun2019 Redesign
Recent  8.2    01Nov2019
Recent  8.3    18Aug2020 SAS 9.4m7
;
 
/* running in SAS EG - modify active ODS to add title to graph */
ods html5(id=eghtml) style=raven gtitle;
 
ods graphics / height=850 width=1200 ;
title font="AvenirNextforSAS Light" height=2.2 
  "SAS Enterprise Guide Releases (1999-2020)";
proc sgplot data=Releases noautolegend;
  styleattrs datacolors=(red yellow green);
  block x=date block=category / transparency = 0.75 
     valueattrs=(weight=bold size=14pt color=yellow 
      family='AvenirNextforSAS Light');
  scatter x=date y=release / datalabel=Details 
    datalabelpos=topleft dataskin=matte
    datalabelattrs=(size=10pt weight=bold)
    markerattrs=(symbol=CircleFilled size=14);
  xaxis grid type=time offsetmax=0.1 offsetmin=0 
        ranges=('01Jan1998'd-'01Jan2021'd) display=(nolabel) ;
  yaxis type=discrete grid offsetmax=0.1 
    label="Release/Event";
  inset "Updated &SYSDATE9." / 
     textattrs=(weight=bold) position=bottomright;
run;
Share

About Author

Chris Hemedinger

Senior Manager, SAS Online Communities

+Chris Hemedinger is the manager of SAS Online Communities. Since 1993, Chris has worked for SAS as an author, a software developer, an R&D manager and a consultant. Inexplicably, Chris is still coasting on the limited fame he earned as an author of SAS For Dummies.  He also hosts the SAS Tech Talk webcasts each year from SAS Global Forum, connecting viewers with smart people from SAS R&D and the impressive work that they do.

12 Comments

  1. Great chart Chris! When you view the EG versions over time, you see how busy the R&D team has been. It's nice to see the SAS version and details as a datalabel. Presents the data very well.

  2. This is great. I remember when I was learning SAS - I tried EG 2.1 and couldn't understand how to use it. But when version 4.1 came around - I was a convert!! Hard to believe that was 2 years difference.

    Thanks for doing this!

    • Chris Hemedinger
      Chris Hemedinger on

      v4.1 was when we changed to have a more process-flow-oriented project. Before that, the EG project was more of a treeview structure...which was limited because not everything can be represented hierarchically.

  3. Hello Chris!
    I tried to run this program changing the data to Enterprise Miner versions. It's not easy to find the dates, not at all... but I have another problem.
    When I run your program I have a '1999' instead of a '2000' in the horizontal axis. I've tried several options with no success.
    What could be happening?
    I'm using Enterprise Guide 7.15 HF8 (7.100.5.6214) (64-bit) with Windows 10 Pro.
    Thanks a lot.

  4. Thanks for updating this Chris; I'm using the data to lobby for our IT group to install 8.2. Fingers crossed!

  5. Chris,

    Can i update to 8.3 from 8.2 version of SAS EG using Check for Updates ? Right now it does not seem to be updating this way.

    • Chris Hemedinger
      Chris Hemedinger on

      I'll have to check with the team, but it might not be available for autoupdate. EG 8.3 doesn't really add any features, but it does update to a newer version of the .NET framework as a baseline. Not sure if that can be delivered via Check for Updates.

    • Chris Hemedinger
      Chris Hemedinger on

      Good question! Since the SAS Studio version is more tied to the version of SAS you are running, this probably would not be as complex as the EG chart.

    • Rick Wicklin

      Not me. I think changes in a GUI are less important than changes in the underlying capabilities of the software. I created the SAS chart for two reasons. First, new features/procedures/statements appear in each release. When you are talking to someone on the Support Communities, it is useful to be able to say that the feature they need is in version 9.x which was released in 20XX. Second, customers sometimes do not realize how old their version of SAS software is. Would you use a smartphone from 10 years ago? In comparison with today's models, a decade-old phone seems clunky and lacks features. The same is true for old versions of computer software.

Leave A Reply

Back to Top