In reply to Andreas Lindberg.

Hi Andreas,

There's not an option to allow you to change the attributes for individual tick values.

One way to create the look of axis tick values with different attributes is to use SG annotation to place text at the X axis tick marks. Annotating the values provides control over each label.

Below is a sample that shows how to do this.

If you have problems getting this to work, you can open a track with SAS Technical Support and we will be happy to provide additional assistance.

data anno;
/* define the X1 drawing space as data values */
x1space='datavalue';
/* define the Y1 drawing space as the percent of the wall area */
y1space='wallpercent';
/* define the annotate function as TEXT */
function='text';
/* set the length for the textcolor variable */
length textcolor $8;
/* set the size of the text font to match the size specified in the YAXIS statement */
textsize=12;
/* define the vertical location under the X axis. This value might need to be adjusted */
y1=-5;
/* define the horizontal location as one of the known tick values */
do x1=11 to 16;
/* define the label to be placed on the graph */
label=put(x1,3.);
/* specify the text color */
if x1=14 then textcolor='red';
else textcolor='black';
output;
end;
run;
/* include the annotate data set using the SGANNO= option */
proc sgplot data=sashelp.class sganno=anno;
styleattrs datacontrastcolors=(pink blue)
datasymbols=(circlefilled squarefilled);
scatter x=age y=height / group=sex markerattrs=(size=10px);
/* Modify the X axis to specify the axis range. Display the values as blank
to create space for the annotated values */
xaxis values=(11 to 16 by 1) valuesdisplay=(' ') labelattrs=(size=14pt);
yaxis valueattrs=(size=12pt) labelattrs=(size=14pt);
keylegend / valueattrs=(size=12pt) titleattrs=(size=14pt);
run;