In reply to Nyi Nyi.

Note that there is not an easy way to write multiple graphs to a single PNG graph file. This is not due to restrictions in SAS, but just the way the PNG graph format was originally designed. But if you need to write multiple graphs to a single PNG graph file, you will need to use the following 3 step process:
Step 1: Use SGPLOT to write multiple PNG graph files to disk.
Step 2: Use PROC GSLIDE with the IBACK graphics option to read the graphs from step 1 back into SAS.
Step 3: Use PROC GREPLAY to "replay" the graphs created in step 2 into a single PNG graph file.
Here is sample SAS code which demonstrates how to put two SGPLOT graphs (one above the other) in a single PNG graph file:

%macro delcat(catname);

%if %sysfunc(cexist(&catname))
%then %do;
proc greplay nofs igout=&catname;
delete _all_;
run;
quit;
%end;
%mend delcat;

%delcat(work.gseg)

%let outdir=%trim(%sysfunc(pathname(work)));

options orientation=landscape nodate nonumber;

goptions reset=all;

/* This step uses multiple PROC SGPLOT procedures */
/* to write multiple PNG files to disk. Note that */
/* this step uses the IMAGENAME= option on the ODS */
/* GRAPHICS ON statement to name each PNG file */
/* that is written to disk. */

ods _all_ close;
ods listing gpath="&outdir" image_dpi=300;

ods graphics on / reset=all imagename='sgplot1'
width=5in height=4in;

title1 'Graph for Females';
proc sgplot data=sashelp.class;
histogram height;
density height;
density height / type=kernel;
where sex="F";
run;

ods graphics on / reset=all imagename='sgplot2'
width=5in height=4in;

title1 'Graph for Males';
proc sgplot data=sashelp.class;
histogram height;
density height;
density height / type=kernel;
where sex="M";
run;

/* This step uses PROC GSLIDE with the IBACK= and */
/* IMAGESTYLE= graphics options to read the PNG */
/* files created in step 1 back into SAS. */

goptions reset=all device=png300 nodisplay
xmax=5in ymax=4in;

goptions iback="&outdir.\sgplot1.png" imagestyle=fit;

proc gslide;
run;
quit;

goptions iback="&outdir.\sgplot2.png" imagestyle=fit;

proc gslide;
run;
quit;

filename grafout 'c:\temp\greplay.png';

goptions reset=all device=PNG300 gsfname=grafout
xmax=5in ymax=8in;

proc greplay igout=work.gseg nofs tc=sashelp.templt
template=V2;
treplay 1:1 2:2;
run;
quit;