In reply to Andy G.

Below is a modified version of the SAS program where the first range includes a superscript -2: In this case I added a new style definition that includes Unicode fonts so the values are resolved correctly in the graph. In addition to defining the style you need to point to the style on your ODS destination statement. In my example, that is the ODS HTML statement.

proc template;
define style unifonts;
parent=Styles.htmlblue;
style Graphfonts from GraphFonts /
'GraphValueFont' = ("Monotype Sans WT J",12pt)
'GraphLabelFont' = ("Monotype Sans WT J",12pt)
'GraphDataFont' = ("Monotype Sans WT J",12pt)
'GraphTitleFont' = ("Monotype Sans WT J",12pt)
'GraphFootnoteFont'=("Monotype Sans WT J",12pt)
'GraphAnnoFont'=("Monotype Sans WT J",12pt);
end;
run;
proc format;
value agefmt
20-30 = "20 (*ESC*){unicode '207b'x}(*ESC*){unicode '00b2'x}"
30-40 = "30 (*ESC*){unicode '2264'x} 40"
40-50 = "40 (*ESC*){unicode '2264'x} 50"
50-60 = "50 (*ESC*){unicode '2264'x} 60"
60-70 = "60 (*ESC*){unicode '2264'x} 70"
;
run;
proc sort data=sashelp.heart out=heart;
by ageatstart;
run;

ods html style=unifonts;
proc sgplot data=heart ;
Title1 "Cholesterol Level by Age Range";
vbox cholesterol / category=AgeAtStart group=AgeAtStart ;
format ageatstart agefmt.;
run;