Rick,
If using SAS/IML 's GA algorithm ,could do this :

data Units;
input Cholesterol @@;
n+1;
cards;
0.4 1.0 1.2 1.7 2.6 2.7
;
run;

proc iml;
use Units nobs nobs;
read all var {Cholesterol};
close;

start function(x) global(Cholesterol,group,sum);
xx=shape(x,group,0,.);
do i=1 to group;
idx=setdif(xx[i,],{.});
temp=Cholesterol[idx];
sum[i]=temp[+];
end;
sse=range(sum);
return (sse);
finish;

group=2; /* <--Change it(divide into 5 groups)*/
sum=j(group,1,.);

id=gasetup(3,nobs,123456789);
call gasetobj(id,0,"function");
call gasetsel(id,10,1,1);
call gainit(id,1000);

niter = 100;
do i = 1 to niter;
call garegen(id);
call gagetval(value, id);
end;
call gagetmem(mem, value, id, 1);

col_mem=shape(mem,group,0,.);

create group from col_mem;
append from col_mem;
close;

print value[l = "Min Value:"] ;
call gaend(id);
quit;

data group;
set group;
group+1;
run;
proc transpose data=group out=member(drop=_: index=(col1));
by group;
var col:;
run;

data want;
merge member(rename=(col1=n) where=(n is not missing)) Units(keep=n Cholesterol);
by n;
run;
proc means data=want sum mean std;
class group;
var Cholesterol;
run;
proc sql;
select * from want order by group,Cholesterol;
quit;