And here's a way to do this by using PROC OPTMODEL in SAS/OR:

proc optmodel;
set OBS;
num x {OBS};
num y {OBS};
read data Circle into OBS=[_N_] x y;
var X0, Y0, R >= 0;
min F = sum {i in OBS} ((x[i] - X0)^2 + (y[i] - Y0)^2 - R^2)^2;
solve;
print X0 Y0 R;
create data sganno from
drawspace='datavalue' function='oval'
heightunit='data' widthunit='data' height=(2*R) width=(2*R)
x1=X0 y1=Y0 radius=R;
quit;

proc sgplot data=Circle sganno=sganno aspect=1;
scatter x=x y=y;
xaxis grid values=(-1 to 5 by 1);
yaxis grid values=( 0 to 6 by 1);
run;