In reply to Edmund.

proc iml;
n = 50; /* number of trials: better approx for 100, 200, etc. */
p = 0.8; /* probability of success for each trial */
mu = n*p;/* classic approximation of binomial pdf by normal pdf */
stddev = sqrt(n*p*(1-p));
xMin = mu - 4*stddev; xMax = mu+4*stddev;
x1 = T(floor(xMin):ceil(xMax)); /* evaluate binomial at integers */
y1 = pdf("Binom", x1, p, n);
x2 = T(do(xMin, xMax, (xMax-xMin)/101));
y2 = pdf("Normal", x2, mu, stddev);
/* write values to SAS data set; plot with SGPLOT */
create HistPlot var {x1 y1 x2 y2}; append; close;

prob = T( do(0.01, 0.99, 0.005) );
q = quantile("binom", prob, p, n); /* ALWAYS an integer! */
qNormal = quantile("normal", prob, mu, stddev);
diff = q - qNormal; /* error from approximating binomial quantiles */
/* write values to SAS data set; plot with SGPLOT */
create CDFPlot var {prob q qNormal}; append; close;
quit;

title "Binomial vs Normal PDF (n=50; p=0.8)";
proc sgplot data=HistPlot;
series x=x2 y=y2 / legendlabel="Normal";
needle x=x1 y=y1 / markers legendlabel="Binomial";
xaxis label="x"; yaxis label="Density";
run;

title "Quantiles: Binomial vs Normal (n=50; p=0.8)";
proc sgplot data=CDFPlot;
series x=prob y=qNormal / legendlabel="Normal Qntl";
scatter x=prob y=q / legendlabel="Binomial Qntl";
xaxis label="Probability"; yaxis label="Binomial Qntl";
run;

/* ZOOM IN: use finer divisions for tail distribution */
proc iml;
n = 50; /* number of trials: better approx for 100, 200, etc. */
p = 0.8; /* probability of success for each trial */
mu = n*p;/* classic approximation of binomial pdf by normal pdf */
stddev = sqrt(n*p*(1-p));
prob = T( do(0.95, 0.999, 0.001) );
q = quantile("binom", prob, p, n); /* ALWAYS an integer! */
qNormal = quantile("normal", prob, mu, stddev);
/* write values to SAS data set; plot with SGPLOT */
create CDFPlot2 var {prob q qNormal}; append; close;
quit;

title "Quantiles in Tail: Binomial vs Normal (n=50; p=0.8)";
proc sgplot data=CDFPlot2;
series x=prob y=qNormal / legendlabel="Normal Qntl";
scatter x=prob y=q / legendlabel="Binomial Qntl";
xaxis label="Probability" min=0.95 max=1;
yaxis label="Binomial Qntl" min=44;
run;