In reply to Jimmy Smith.

Sure, lots of ways. Here's an example of using the OUTPUT statement to score the model on the training data:

/* 1. subset about 40% of data for training */
data training;
set sashelp.cars;
if rand("Bernoulli", 0.4);
run;
/* 2. fit model on training; score model */
proc reg data=training noprint;
model weight = wheelbase;
output out=PredTrain(rename=(wheelbase=x)) p=Pred;
quit;
/* 3. sort fit by x */
proc sort data=PredTrain(keep=x Pred);
by x;
run;
/* 4. merge the original data and the fit on the training data */
data All;
set sashelp.cars /* original */
PredTrain; /* model on training */
run;

title "Regression on Training";
title2 "All Observations Displayed";
proc sgplot data=All noautolegend;
scatter x=wheelbase y=weight;
series x=x y=Pred;
run;