%let gpath=C:\;
ods html close;
%let w=4in;
%let h=2in;
%let dpi=200;
ods listing gpath="&gpath" image_dpi=&dpi;

/*--Gradient--*/
title 'SAS 9.4M5 Gradient Bars';
ods graphics / reset width=&w height=&h imagename='Gradient_94M5';
proc sgplot data=sashelp.cars(where=(type ne 'Hybrid')) noborder;
  vbar type / response=mpg_city stat=mean filltype=gradient
       displaybaseline=auto;
  yaxis display=(noline);
  xaxis display=(nolabel noline noticks);
run;

/*--Gradient Grid--*/
title 'SAS 9.4M5 Gradient Bars';
ods graphics / reset width=&w height=&h imagename='Gradient_Grid_94M5';
proc sgplot data=sashelp.cars(where=(type ne 'Hybrid')) noborder;
  vbar type / response=mpg_city stat=mean filltype=gradient
      displaybaseline=auto;
  yaxis grid display=(noticks noline);
  xaxis display=(nolabel noline noticks);
run;

/*--Gradient Alpha--*/
title 'SAS 9.4M5 Gradient Two Color Bars';
ods graphics / reset width=&w height=&h imagename='Gradient_Alpha_94M5';
proc sgplot data=sashelp.cars(where=(type ne 'Hybrid')) noborder;
  vbar type / response=mpg_city stat=mean filltype=alphagradient
      displaybaseline=auto ;
  yaxis grid display=(noticks noline);
  xaxis display=(nolabel noline noticks);
run;

/*--Gradient Grid with 2nd color--*/
title 'SAS 9.4M5 Gradient Two Color Bars';
ods graphics / reset width=&w height=&h imagename='Gradient_Two_Color_94M5';
proc sgplot data=sashelp.cars(where=(type ne 'Hybrid')) noborder;
  vbar type / response=mpg_city stat=mean filltype=gradient
      displaybaseline=auto fillattrs=graphdata2 fillendcolor=yellow;
  yaxis grid display=(noticks noline);
  xaxis display=(nolabel noline noticks);
run;

/*--Gradient Grid with 2nd color--*/
title 'SAS 9.4M5 Gradient Two Color Bars';
ods graphics / reset width=&w height=&h imagename='Gradient_Two_Color_2_94M5';
proc sgplot data=sashelp.cars(where=(type ne 'Hybrid')) noborder;
  vbar type / response=mpg_city stat=mean filltype=gradient
      displaybaseline=auto fillattrs=graphdata2 fillendcolor=darkred;
  yaxis grid display=(noticks noline);
  xaxis display=(nolabel noline noticks);
run;

/*--Gradient Grid with 2nd color and skin--*/
title 'SAS 9.4M5 Gradient Two Color Bars';
ods graphics / reset width=&w height=&h imagename='Gradient_Two_Color_Skin_94M5';
proc sgplot data=sashelp.cars(where=(type ne 'Hybrid')) noborder;
  vbar type / response=mpg_city stat=mean filltype=gradient dataskin=matte
      displaybaseline=auto fillattrs=graphdata2 fillendcolor=darkred;
  yaxis grid display=(noticks noline);
  xaxis display=(nolabel noline noticks);
run;

/*--Gradient Grid with 2nd color and skin--*/
title 'Distribution of City Mileage';
ods graphics / reset width=&w height=&h imagename='Hist_Two_Color_Skin_94M5';
proc sgplot data=sashelp.cars(where=(type ne 'Hybrid')) noborder;
  histogram mpg_city /  filltype=gradient dataskin=matte fillattrs=(color=silver) fillendcolor=cx5f5f5f;
  yaxis grid display=(noticks noline);
  xaxis display=(nolabel noline noticks);
run;