%let gpath='.';
%let dpi=200;
ods html close;
ods listing gpath=&gpath image_dpi=&dpi;

/*--Data set--*/
data age;
  input Name $1-10 Type $11-20 Age;
  ximg=-7;
  datalines;
Bear      Mammal    37
Camel     Mammal    43
Turtle    Other     44
Elephant  Mammal    49
Parrot    Bird      66
;
run;

/*--Icon File Names--*/
%let parrot=C:\Parrot_Trans.png;
%let elephant=C:\Elephant_Trans.png;
%let turtle=C:\Turtle_Trans.png;
%let camel=C:\Camel_Trans.png;
%let bear=C:\Bear_Trans.png;

/*--Render plot--*/
ods graphics / reset width=5in height=3in imagename='Age';
title 'Life Expectancy';
proc sgplot data=age nowall noborder;
  /*--Define marker symbols--*/
  symbolimage name=parrot image="&parrot" / voffset=-0.2;
  symbolimage name=elephant image="&elephant";
  symbolimage name=turtle image="&turtle";
  symbolimage name=camel image="&camel";
  symbolimage name=bear image="&bear";

  styleattrs datasymbols=(bear camel turtle elephant parrot);
  scatter x=ximg y=name / group=name markerattrs=(size=60);
  hbarparm category=name response=age / baselineattrs=(thickness=0) 
      dataskin=matte filltype=gradient fillattrs=graphdata1;
  xaxis display=(nolabel noline noticks) grid offsetmin=0.07 offsetmax=0.07;
  yaxis fitpolicy=none discreteorder=data  display=none offsetmin=0.1 offsetmax=0.1;
run;