%let gpath=C:\;
ods html close;
%let w=4in;
%let h=2in;
%let dpi=200;
ods listing gpath="&gpath" image_dpi=&dpi;

/*--Histogram--*/
ods graphics / reset width=&w height=&h imagename='Histogram';
title 'Distribution of Cholesterol';
proc sgplot data=sashelp.heart;
  histogram cholesterol;
run;

/*--Histogram Density--*/
ods graphics / reset width=&w  height=&h imagename='Histogram_Density_Offset';
title 'Distribution of Cholesterol';
proc sgplot data=sashelp.heart;
  histogram cholesterol;
  density cholesterol;
  keylegend / location=inside position=topright across=1 noborder;
run;

/*--Histogram 2 Densities--*/ ;
ods graphics / reset width=&w  height=&h imagename='Histogram_Density_2_Offset';
title 'Distribution of Cholesterol';
proc sgplot data=sashelp.heart;
  histogram cholesterol;
  density cholesterol;
  density cholesterol / type=kernel;
  keylegend / location=inside position=topright across=1 noborder;
run;

/*--Histogram 2 Densities--*/
ods graphics / reset width=&w height=&h imagename='Histogram_Density_2_Solid_No_Offset';
title 'Distribution of Cholesterol';
proc sgplot data=sashelp.heart noautolegend;
  histogram cholesterol;
  density cholesterol;
  density cholesterol / type=kernel lineattrs=(pattern=solid);
  keylegend / location=inside position=topright across=1 noborder;
  yaxis offsetmin=0;
run;

/*--Histogram overlay--*/
ods graphics / reset width=&w height=&h imagename='Histogram_Overlay';
title 'Distribution of Blood Pressure';
proc sgplot data=sashelp.heart nocycleattrs;
  histogram systolic / fillattrs=graphdata1 name='s' binstart=50 binwidth=5;
  density systolic / lineattrs=graphdata1;
  histogram diastolic / fillattrs=graphdata2 name='d' binstart=50 binwidth=5;
  density diastolic / lineattrs=graphdata2;
  keylegend 's' 'd' / location=inside position=topright across=1 noborder;
  yaxis offsetmin=0;
  xaxis display=(nolabel);
run;

/*--Create data set with BP a group--*/
data heart;
  length Group $9;
  keep group bp;
  set sashelp.heart(keep=systolic diastolic);
  Group='Systolic'; bp=systolic; output;
  Group='Diastolic'; bp=diastolic; output;
run;
proc print;run ;

/*--Histogram groups--*/
ods graphics / reset width=&w height=&h imagename='Histogram_Group';
title 'Distribution of Blood Pressure';
proc sgplot data=heart noborder;
  histogram bp / group=group name='a' transparency=0.5;
  density bp  / group=group;
  keylegend 'a' / location=inside position=topright across=1 noborder;
  yaxis offsetmin=0 display=(noline noticks) grid;
  xaxis display=(nolabel);
run;

/*--Histogram Label--*/
ods graphics / reset width=&w height=&h imagename='Histogram_Labels';
title 'Distribution of Cholesterol';
proc sgplot data=sashelp.heart;
  format cholesterol percent 4.1;
  histogram cholesterol / scale=count datalabel;
  yaxis offsetmin=0;
  xaxis display=(nolabel);
run;