%let gpath=C:\;
%let dpi=200;
ods html close;
ods listing gpath="&gpath" image_dpi=&dpi;
/*--Graph with regular axis--*/
ods graphics / reset width=5in height=3in imagename='Heart1';
proc sgplot data=sashelp.heart;
vbar deathcause;
run;
/*--Subset number of cars--*/
data carssubset;
set sashelp.cars(where=(origin='Asia' and type='Sports'));
run;
/*--Sort by Model--*/
proc sort data=carssubset out=carssubset;
by model;
run;
/*--Graph with regular axis--*/
ods graphics / reset width=5in height=3in imagename='Cars1';
proc sgplot data=carssubset;
vbar model / response=mpg_city dataskin=matte fillattrs=graphdata2;
run;
/*--Find all categories--*/
proc means data=carssubset noprint;
class model;
output out=cars(where=(_type_ eq 1))
mean=mean;
run;
/*--Create annotation data set for all categories--*/
data anno;
set carssubset(keep=model);
by model;
if first.model then do;
id='a'; function='text'; x1space='datavalue'; y1space='wallpercent'; label=model;
xc1=model; y1=-3; anchor='right'; width=60; rotate=45; output;
end;
run;
/*--Graph with custom diagonal axis--*/
ods graphics / reset width=5in height=3in imagename='Cars2';
proc sgplot data=carssubset sganno=anno pad=(bottom=45pct left=25pct);
vbar model / response=mpg_city dataskin=pressed
filltype=gradient fillattrs=graphdata3;
xaxis display=(novalues nolabel);
run;
/*--Graph with custom diagonal axis--*/
ods graphics / reset width=5in height=3in imagename='Cars3';
proc sgplot data=carssubset sganno=anno pad=(bottom=45pct left=25pct);
vbar model / response=mpg_city dataskin=pressed
filltype=gradient fillattrs=graphdata4;
xaxis display=(novalues nolabel) reverse;
run;
/*--HBar--*/
ods graphics / reset width=4in height=3in imagename='Cars_HBar';
proc sgplot data=carssubset;
hbar model / response=mpg_city fillattrs=graphdata6 dataskin=pressed filltype=gradient;
yaxis valueattrs=(size=7);
run;