%let gpath='.';
ods html close;
%let dpi=200;
ods listing gpath=&gpath image_dpi=&dpi;
title;
footnote;
/*--Create data set--*/
data financial;
input Cat $ Res1 Res2 Res3;
if cat ne 'I' then do; res2m=res2; res3m=res3; end;
datalines;
A 10 15 70
B 20 30 60
C 16 25 50
D 14 20 60
E 30 40 50
F 28 33 55
G 26 30 51
H 40 50 63
I 15 70 10
;
run;
/*--Bar and Series with Arrowhead--*/
ods listing image_dpi=200;
ods graphics / reset width=4in height=3in imagename='SeriesArrow1';
proc sgplot data=financial noautolegend;
vbarbasic cat / response=res1 dataskin=pressed;
series x=cat y=res2 / arrowheadpos=end arrowheadshape=filled
lineattrs=(thickness=10 color=blue) dataskin=pressed;
series x=cat y=res3 / arrowheadpos=end arrowheadshape=filled
lineattrs=(thickness=10 color=red) dataskin=pressed;
run;
title;
/*--Bar and Series with Arrowhead no axes or wall frame--*/
ods listing image_dpi=200;
ods graphics / reset width=4in height=3in imagename='SeriesArrow2';
proc sgplot data=financial noborder noautolegend;
vbarbasic cat / response=res1 dataskin=pressed
baselineattrs=(thickness=0);
series x=cat y=res2 / arrowheadpos=end arrowheadshape=filled
lineattrs=(thickness=10 color=blue) dataskin=pressed
markers markerattrs=(symbol=circlefilled size=14)
filledoutlinedmarkers markerfillattrs=(color=white);
series x=cat y=res3 / arrowheadpos=end arrowheadshape=filled
lineattrs=(thickness=10 color=red) dataskin=pressed
markers markers markerattrs=(symbol=circlefilled size=14)
filledoutlinedmarkers markerfillattrs=(color=white);
xaxis display=none;
yaxis display=none offsetmin=0;
run;
title;
/*--Bar and Series with Arrowhead Final--*/
ods listing image_dpi=200;
ods graphics / reset width=4in height=3in imagename='SeriesArrow3';
proc sgplot data=financial noborder noautolegend;
vbarbasic cat / response=res1 dataskin=gloss fillattrs=(color=silver)
baselineattrs=(thickness=0) barwidth=0.7;
series x=cat y=res2 / arrowheadpos=end arrowheadshape=barbed
lineattrs=(thickness=10 color=cx3f8fdf) dataskin=sheen;
scatter x=cat y=res2m /
markerattrs=(symbol=circlefilled size=14)
filledoutlinedmarkers markerfillattrs=(color=white);
series x=cat y=res3 / arrowheadpos=end arrowheadshape=barbed
lineattrs=(thickness=10 color=cxdf2f3f) dataskin=sheen;
scatter x=cat y=res3m /
markerattrs=(symbol=circlefilled size=14)
filledoutlinedmarkers markerfillattrs=(color=white);
xaxis display=none;
yaxis display=none offsetmin=0;
run;
title;