%let gpath='.';
ods html close;


data sales;
  format Value percent8.0;
  input Group $1-25 Category $26-50 Value;
  datalines;
Your Sales Figures         Western States Region    0.68
Your Sales Figures         Mountain States Region   0.49
Your Sales Figures         Central States Region    0.77
Your Sales Figures         Eastern States Region    0.06
Your Peer's Sales Figures  Western States Region    0.70
Your Peer's Sales Figures  Mountain States Region   0.46
Your Peer's Sales Figures  Central States Region    0.73
Your Peer's Sales Figures  Eastern States Region    0.10
;
run;

/*--Bubble Plot--*/
%let dpi=200;
ods listing image_dpi=&dpi gpath=&gpath;
ods graphics / reset width=4in height=1.75in noborder imagename='Sales_Bubble';
title 'Sales by Region';
proc sgplot data=sales noborder noautolegend;
  bubble y=Group x=Category size=value / bradiusmax=25 bradiusmin=12 
         group=category dataskin=pressed datalabel=value 
         datalabelpos=center datalabelattrs=(color=white size=8 weight=bold);
  yaxis display=(noline noticks nolabel) fitpolicy=split valueattrs=(size=8);
  xaxis display=(nolabel noticks noline) valueattrs=(size=8);
run;

/*--Bar Chart--*/
%let dpi=200;
ods listing image_dpi=&dpi gpath=&gpath;
ods graphics / reset width=4in height=2.5in noborder imagename='Sales_Bar';
title 'Sales by Region';
proc sgplot data=sales noborder;
  styleattrs datacolors=(darkgreen gold);
  vbarparm category=Category response=value / group=Group 
           groupdisplay=cluster dataskin=pressed datalabel
           datalabelattrs=(color=black size=8 weight=bold);
  keylegend / title='';
  yaxis display=(noline noticks nolabel) grid valueattrs=(size=8);
  xaxis display=(nolabel noticks) valueattrs=(size=8);
run;