%let gpath='C:\';
%let dpi=200;
ods html close;

proc format;
  value item
    1='Draft Document'
    2='Final Document'
    3='Design / Acquision'
    4='Award Contract'
    5='Construction'
    6='Closeout';
	run;

data schedule;
  input Item $1-20 Group $21-30 Start End  id;
  format Start End Start2 End2 monyy7.;
  informat Start End date9.;
  start2=start+30; end2=end+30;
  if group='Baseline' then id2=id+0.25;
  else id2=id-0.25;
  id3=id2+0.05;
  datalines;
Draft Document      Baseline  01Jun2005  01Mar2008  1
Final Document      Baseline  01Mar2008  01Mar2009  2
Design / Acquision  Baseline  01Mar2009  01Jan2012  3
Award Contract      Baseline  01Jan2012  01Apr2012  4
Construction        Baseline  01Apr2012  01Jan2015  5
Closeout            Baseline  01Jan2015  01Jan2018  6
Draft Document      Current   01Jan2006  01Jun2011  1
Final Document      Current   01Jun2011  01Oct2011  2
Design / Acquision  Current   01Oct2011  01Nov2011  3
Award Contract      Current   01Nov2011  01May2012  4
Construction        Current   01May2012  01Jan2015  5
Closeout            Current   01Jan2015  01Jan2018  6
;
run;

ods html;
proc print noobs;
  var item group start end id id2 id3;
run;
ods html close;
  
%modstyle (name=schedule, parent=htmlblue, colors=cxAC9411 cx315cb0, fillcolors=cxFCB441 cx418cf0);
run;

ods listing style=schedule gpath=&gpath image_dpi=&dpi;

/*--Basic Schedule Chart--*/
ods graphics / reset width=5in height=3in imagename='Schedule_Line_93_1';
proc sgplot data=schedule(where=(group eq 'Baseline')) noautolegend;
  title 'Schedule for Mid-Atlantic Light Rail (SAS 9.3)';
  format id item.;
  step y=id x=start / lineattrs=(thickness=3);
  highlow y=id low=start high=end / type=bar  intervalbarwidth=20 name='a';
  yaxis reverse display=(nolabel) grid;
  xaxis display=(nolabel) grid;
/*  keylegend 'a' / location=inside position=topright across=1;*/
  run;

%modstyle (name=schedule, parent=htmlblue, colors=cxCC8431 cx315cb0, fillcolors=cxFCB441 cx418cf0);
run;

ods listing style=schedule gpath=&gpath image_dpi=&dpi;

/*--Schedule Chart with Drop Shadows--*/
ods graphics / reset width=5in height=3in imagename='Schedule_Line_93_2';
proc sgplot data=schedule;
  title 'Schedule for Mid-Atlantic Light Rail (SAS 9.3)';
  format id2 id3 item.;
  highlow y=id3 low=start2 high=end2 / type=bar fillattrs=(color=gray) 
           intervalbarwidth=15 name='a' lineattrs=(color=gray);
  step y=id2 x=start / group=group groupdisplay=cluster lineattrs=(thickness=3);
  highlow y=id2 low=start high=end / type=bar group=group 
           intervalbarwidth=15 name='a' lineattrs=(color=black);
  yaxis reverse display=(nolabel) grid values=(1 to 6 by 1) offsetmin=0.1 offsetmax=0.1;
  xaxis display=(nolabel) grid;
  keylegend 'a' / location=inside position=topright across=1;
  run;