%let gpath='C:\';
%let dpi=200;
ods html close;

data schedule;
  input Item $1-30 Group $31-40 Start End;
  format Start End Start2 End2 monyy7.;
  informat Start End date9.;
  start2=start+30; end2=end+30;
  datalines;
Draft Environmental Document  Baseline   01Jun2005  01Mar2008
Final Environmental Document  Baseline  01Mar2008  01Mar2009
Design Right-of-way Acquision Baseline  01Mar2009  01Jan2012
Award Construction Contract   Baseline  01Jan2012  01Apr2012
Construction                  Baseline  01Apr2012  01Jan2015
Closeout                      Baseline  01Jan2015  01Jan2018
Draft Environmental Document  Current   01Jan2006  01Jun2011
Final Environmental Document  Current   01Jun2011  01Oct2011
Design Right-of-way Acquision Current   01Oct2011  01Nov2011
Award Construction Contract   Current   01Nov2011  01May2012
Construction                  Current   01May2012  01Jan2015
Closeout                      Current   01Jan2015  01Jan2018
;
run;
/*proc print;run;*/
  
%modstyle (name=schedule, parent=htmlblue, colors=black black, fillcolors=cxFCB441 cx418cf0);
run;

ods listing style=schedule gpath=&gpath image_dpi=&dpi;

/*--Basic Schedule Chart--*/
ods graphics / reset width=5in height=3.5in imagename='Schedule_94_1';
proc sgplot data=schedule;
  title 'Schedule for Mid-Atlantic Light Rail';
  highlow y=item low=start high=end / type=bar group=group  
          groupdisplay=cluster barwidth=0.9 name='a';
  yaxis reverse display=(nolabel) fitpolicy=splitalways valueattrs=(size=7) grid;
  xaxis display=(nolabel) min='01jan2005'd max='01jan2018'd grid;
  keylegend 'a' / location=inside position=topright across=1;
  run;

/*--Basic Schedule Chart with Drop Shadows--*/
ods graphics / reset width=5in height=3.5in imagename='Schedule_94_2';
proc sgplot data=schedule;
  title 'Schedule for Mid-Atlantic Light Rail';
  highlow y=item low=start2 high=end2 / type=bar group=group nooutline transparency=0.5 
          groupdisplay=cluster barwidth=0.9 fillattrs=(color=gray) discreteoffset=0.05;
  highlow y=item low=start high=end / type=bar group=group  
          groupdisplay=cluster barwidth=0.9 name='a';
  yaxis reverse display=(nolabel) fitpolicy=splitalways valueattrs=(size=7) grid;
  xaxis display=(nolabel) min='01jan2005'd max='01jan2018'd grid;
  keylegend 'a' / location=inside position=topright across=1;
  run;

/*--Basic Schedule Chart with Drop Shadows and Color Bands--*/
ods graphics / reset width=5in height=3.5in imagename='Schedule_94_3';
proc sgplot data=schedule;
  title 'Schedule for Mid-Atlantic Light Rail';
  highlow y=item low=start2 high=end2 / type=bar group=group nooutline transparency=0.5 
          groupdisplay=cluster barwidth=0.9 fillattrs=(color=gray) discreteoffset=0.05;
  highlow y=item low=start high=end / type=bar group=group  
          groupdisplay=cluster barwidth=0.9 name='a';
  yaxis reverse display=(nolabel) colorbands=odd colorbandsattrs=(transparency=0.5)
        fitpolicy=splitalways valueattrs=(size=7);
  xaxis display=(nolabel) min='01jan2005'd max='01jan2018'd grid;
  keylegend 'a' / location=inside position=topright across=1;
  run;