%let gpath='C:\';
%let dpi=200;
ods html close;

data schedule;
  input Item $1-20 Group $21-30 Start End;
  format Start End Start2 End2 monyy7.;
  informat Start End date9.;
  start2=start+30; end2=end+30;
  datalines;
Draft Document      Baseline  01Jun2005  01Mar2008
Final Document      Baseline  01Mar2008  01Mar2009
Design / Acquision  Baseline  01Mar2009  01Jan2012
Award Contract      Baseline  01Jan2012  01Apr2012
Construction        Baseline  01Apr2012  01Jan2015
Closeout            Baseline  01Jan2015  01Jan2018
Draft Document      Current   01Jan2006  01Jun2011
Final Document      Current   01Jun2011  01Oct2011
Design / Acquision  Current   01Oct2011  01Nov2011
Award Contract      Current   01Nov2011  01May2012
Construction        Current   01May2012  01Jan2015
Closeout            Current   01Jan2015  01Jan2018
;
run;
/*proc print;run;*/
  
%modstyle (name=schedule, parent=htmlblue, colors=black black, fillcolors=cxFCB441 cx418cf0);
run;

ods listing style=schedule gpath=&gpath image_dpi=&dpi;

/*--Basic Schedule Chart--*/
ods graphics / reset width=5in height=3in imagename='Schedule_93_1';
proc sgplot data=schedule;
  title 'Schedule for Mid-Atlantic Light Rail';
  highlow y=item low=start high=end / type=bar group=group 
          groupdisplay=cluster barwidth=0.9 name='a';
  yaxis reverse display=(nolabel) grid;
  xaxis display=(nolabel) grid;
  keylegend 'a' / location=inside position=topright across=1;
  run;

/*--Schedule Chart with Drop Shadows--*/
ods graphics / reset width=5in height=3in imagename='Schedule_93_2';
proc sgplot data=schedule;
  title 'Schedule for Mid-Atlantic Light Rail';
  highlow y=item low=start2 high=end2 / type=bar group=group nooutline transparency=0.5 
          groupdisplay=cluster barwidth=0.9 fillattrs=(color=gray) discreteoffset=0.05;
  highlow y=item low=start high=end / type=bar group=group 
          groupdisplay=cluster barwidth=0.9 name='a';
  yaxis reverse display=(nolabel) grid;
  xaxis display=(nolabel) grid;
  keylegend 'a' / location=inside position=topright across=1;
  run;