%let gpath='C:\';
%let dpi=150;
%let w=3.5in;
%let h=2.0in;
ods html close;
ods listing gpath=&gpath image_dpi=&dpi;
title;

/*--Compute car statistics--*/
proc means data=sashelp.cars noprint;
  class type origin;
  var mpg_city;
  output out=cars
         mean=Mean
         max=max
         min=min;
run;

/*--Style Attrs 93--*/
ods graphics / reset width=&w height=&h  imagename='Style_Attrs_Needle_93';
title 'Mileage by Origin and Type';
proc sgplot data=cars(where=(type in ('Sedan' 'Sports' 'SUV')));
  needle x=origin y=max /  group=type groupdisplay=cluster clusterwidth=0.5
         lineattrs=(thickness=5) markers markerattrs=(size=11 color=gray) 
         nomissinggroup;
  xaxis display=(nolabel);
  run;

/*--Style Attrs 94--*/
ods graphics / reset width=&w height=&h  imagename='Style_Attrs_Needle_94';
title 'Mileage by Origin and Type';
proc sgplot data=cars(where=(type in ('Sedan' 'Sports' 'SUV')));
  styleattrs datacontrastcolors=(purple green orange)
             datasymbols=(circlefilled trianglefilled squarefilled )
             datalinepatterns=(solid);
  needle x=origin y=max /  group=type groupdisplay=cluster clusterwidth=0.5
         lineattrs=(thickness=5) markers markerattrs=(size=11 color=gray) 
         nomissinggroup;
  xaxis display=(nolabel);
  run;

/*--Attr Priority Series 93--*/
ods graphics / reset width=&w height=&h imagename='Attr_Priority_Series_93';
title 'Monthly Close by Stock';
proc sgplot data=sashelp.stocks(where=(date > '01Jan2001'd));
  series x=date y=close / group=stock lineattrs=(thickness=2);
  xaxis display=(nolabel);
  yaxis display=(nolabel);
  run;

/*--Attr Priority Series 94--*/
ods graphics / reset attrpriority=color width=&w height=&h imagename='Attr_Priority_Series_94';
title 'Monthly Close by Stock';
proc sgplot data=sashelp.stocks(where=(date > '01Jan2001'd));
  series x=date y=close / group=stock lineattrs=(thickness=2);
  xaxis display=(nolabel);
  yaxis display=(nolabel);
  run;