%let gpath='C:\';
%let dpi=100;

ods html close;
ods listing gpath=&gpath image_dpi=&dpi;

/*--Data--*/
data unicode;
  length Cat $10;
  input Cat $ Response;
  datalines;
SIGMA  16
RSquare 21
Alpha+Beta  18
Sigma1   22
LE10     16.5
;
run;
proc print;run;

/*--Bar Chart of Height for Male Students--*/
proc template;
  define statgraph Unicode1;
    begingraph;
      entrytitle 'Response by Category';
      layout overlay / xaxisopts=(display=(ticks tickvalues) discreteopts=(ticktype=inbetween))
                       yaxisopts=(griddisplay=on);
	    barchart x=cat y=Response / stat=mean dataskin=gloss;
	  endlayout;
	endgraph;
  end;
run;

ods graphics / reset width=5in height=3in imagename='Unicode1';
proc sgrender data=unicode template=Unicode1;
run;

/*--Bar Chart with Unicode tick values--*/
ods escapechar = '~';
proc template;
  define statgraph Unicode2;
    begingraph / pad=(bottom=20px) ;
      entrytitle 'Response by Category';
      layout overlay / xaxisopts=(display=(ticks) discreteopts=(ticktype=inbetween))
                       yaxisopts=(griddisplay=on);
	 barchart x=cat y=Response / stat=mean dataskin=gloss;
	 drawtext '~{unicode "03a3"x}' / x='SIGMA' y=-1 anchor=top
                 xspace=datavalue yspace=wallpercent;
	 drawtext 'r' {sup "2"} /  x='RSquare' y=-1 anchor=top
		         xspace=datavalue yspace=wallpercent;
	 drawtext '~{unicode "03b1"x} + ~{unicode "03b2"x}' /  x='Alpha+Beta' y=-1 
                 anchor=top xspace=datavalue yspace=wallpercent;
	 drawtext '~{unicode "03c3"x}' {sub "1"} / x='Sigma1' y=-1 anchor=top
                 xspace=datavalue yspace=wallpercent;
	 drawtext '~{unicode "2264"x} 10'  /  x='LE10' y=-1 anchor=top
                 xspace=datavalue yspace=wallpercent;
	endlayout;
      endgraph;
  end;
run;

ods graphics / reset width=5in height=3in imagename='Unicode2';
proc sgrender data=unicode template=Unicode2;
run;