data TallBar;
  input X $ Y;
  high=y; low=0;
  if y > 20 then do; high=20; highcap=20; end;
  datalines;
A  10
B  15
C  12
D  17
E  215
F  220
;
run;


/*--Panel Break with Arrows--*/
proc template;
  define statgraph High_Low;
    begingraph;
      entrytitle 'Panel Break with Arrows';
      layout lattice / rows=2 columndatarange=union rowweights=(0.5 0.5) rowgutter=2;
	columnaxes;
	  columnaxis / tickvalueattrs=(size=7) display=(ticks tickvalues) 
                       offsetmin=0.1 offsetmax=0.1;
	endcolumnaxes;
        layout overlay / yaxisopts=(display=(ticks tickvalues) offsetmin=0 
                            griddisplay=on tickvalueattrs=(size=7) );
	  barchart x=x y=y / fillattrs=graphdata1 barwidth=0.5;
	endlayout;
        layout overlay / yaxisopts=(display=(ticks tickvalues) offsetmin=0
                         griddisplay=on tickvalueattrs=(size=7)) ;
          scatterplot x=x y=eval(highcap+2) / 
             markerattrs=(symbol=trianglefilled color=black size=31);
          barchart x=x y=high / fillattrs=graphdata1 barwidth=0.5;
          scatterplot x=x y=eval(highcap+2) / 
             markerattrs=(symbol=trianglefilled color=graphdata1:color size=29);
        endlayout;
      endlayout;
    endgraph;
  end;
run;

ods listing image_dpi=150;
ods graphics / reset width=2in height=3in imagename='High_Low_92';
proc sgrender data=TallBar template=High_Low;
run;