%let gpath='C:\';

/*--Car Histogram Template--*/
proc template;
  define statgraph CarHist1;
    dynamic _dpi;
    begingraph;
      entrytitle 'Distribution of Mileage';
	  entryfootnote halign=left 'DPI= ' _dpi;
      layout lattice / columns=1 rowweights=(0.8 0.2) columndatarange=union;
	    columnaxes;
		  columnaxis;
	    endcolumnaxes;
        layout overlay;
	      histogram mpg_city;
		  densityplot mpg_city / kernel() name='k' legendlabel='Kernel';
          discretelegend 'k' / location=inside halign=right valign=top;
		endlayout;
        layout overlay;
	      boxplot y=mpg_city / orient=horizontal;
		endlayout;
	  endlayout;
	endgraph;
  end;
run;

/*--Car Histogram Graph--*/
ods listing style=listing image_dpi=100 gpath=&gpath;
ods graphics / reset imagename='CarHist1';
proc sgrender data=sashelp.cars template=CarHist1;
dynamic _dpi='100';
run;

/*--Car Histogram Graph--*/
ods listing image_dpi=300;
ods graphics / reset imagename='CarHist1_300';
proc sgrender data=sashelp.cars template=CarHist1;
dynamic _dpi='300';
run;

/*--Car Histogram Graph--*/
ods listing image_dpi=100;
ods graphics / reset height=2.4in imagename='CarHist2_100';
proc sgrender data=sashelp.cars template=CarHist1;
dynamic _dpi='100';
run;

/*--Car Histogram Graph--*/
ods listing image_dpi=300;
ods graphics / reset height=2.4in imagename='CarHist2_300';
proc sgrender data=sashelp.cars template=CarHist1;
dynamic _dpi='300';
run;

/*--Car Histogram Template with design size--*/
proc template;
  define statgraph CarHistSize;
    dynamic _h _w;
    begingraph / designwidth=_w designheight=_h;
      entrytitle 'Distribution of Mileage';
	  entryfootnote halign=left 'DesignHeight= ' _h;
      layout lattice / columns=1 rowweights=(0.8 0.2) columndatarange=union;
	    columnaxes;
		  columnaxis;
	    endcolumnaxes;
        layout overlay;
	      histogram mpg_city;
		  densityplot mpg_city / kernel() name='k' legendlabel='Kernel';
          discretelegend 'k' / location=inside halign=right valign=top;
		endlayout;
        layout overlay;
	      boxplot y=mpg_city / orient=horizontal;
		endlayout;
	  endlayout;
	endgraph;
  end;
run;

/*--Car Histogram Graph DH=4.5--*/
ods listing style=listing image_dpi=200 gpath=&gpath;
ods graphics / reset height=2.4in imagename='CarHist45';
proc sgrender data=sashelp.cars template=CarHistSize;
  dynamic _w='6in' _h='4.5in';
run;

/*--Car Histogram Graph DH=4.0--*/
ods listing style=listing image_dpi=200 gpath=&gpath;
ods graphics / reset height=2.4in  imagename='CarHist40';
proc sgrender data=sashelp.cars template=CarHistSize;
  dynamic _w='5.33in' _h='4.0in';
run;

/*--Car Histogram Graph DH=3.6--*/
ods listing style=listing image_dpi=200 gpath=&gpath;
ods graphics / reset height=2.4in  imagename='CarHist36';
proc sgrender data=sashelp.cars template=CarHistSize;
  dynamic _w='4.8in' _h='3.6in';
run;