data bank;
  input Date $ Group $ Balance Unemployment;
  format balance dollar.;
  datalines;
2011Q1  MyBank  1700   8.8
2011Q1  Peer    2000   .
2011Q2  MyBank  1600   9.0
2011Q2  Peer    1800   .
2011Q3  MyBank  1650   8.9
2011Q3  Peer    1750   .
2011Q4  MyBank  1700   8.6
2011Q4  Peer    1700   .
;
run;


ods listing;
ods graphics / reset width=5in height=3in imagename='Bank';
title 'Quarterly Bank Portfolio and Unemployment';
proc sgplot data=bank;
  vbarparm category=date response=balance / group=group dataskin=gloss name='b';
  series x=date y=Unemployment / y2axis name='u' legendlabel='Unemployment' 
         lineattrs=(thickness=10) transparency=0.4;
  keylegend 'b' 'u';
  xaxis display=(nolabel);
  yaxis offsetmin=0 grid;
  y2axis offsetmin=0 min=0 max=12 integer values=(0 3 6 9 12);
  run;


ods graphics / reset width=5in height=3in imagename='Bank_Vbar';
title 'Quarterly Bank Portfolio and Unemployment';
proc sgplot data=bank;
  vbar date / response=balance group=group dataskin=gloss name='b' groupdisplay=cluster nostatlabel;
  vline date / response=unemployment group=group y2axis name='u' nostatlabel
         lineattrs=graphdatadefault(thickness=10) transparency=0.4;
  keylegend 'b' 'u';
  xaxis display=(nolabel);
  yaxis offsetmin=0 grid;
  y2axis offsetmin=0 min=0 max=12 integer values=(0 3 6 9 12);
  run;