%let gpath='.';
%let dpi=200;
ods html close;
ods listing gpath=&gpath image_dpi=&dpi;

data dot;
  format Pct percent8.1;
  label pct='%';
  label classification='System Organ Classification';
  input Value Classification $6-65;
  Pct=Value/100;
  datalines;
 1.6  Infections and infestations
11.4  Neoplasms benign and malignant (incl. cysts and polyps)
 6.5  Blood and the lymphatic system disorders
10.5  Immune system disorders
 6.8  Endocrine disorders
 8.4  Metabolism and nutrition disorders
 8.4  Psychiatric disorders
10.7  Nervous system disorders
 7.9  Eye disorders
 9.3  Ear and labyrinth disorders
12.8  Cardiac disorders
 7.9  Vascular disorders
 6.3  Respiratory, thoracic and mediastinal disorders
15.1  Gastrointestinal disorders
 8.5  Hepato-biliary disorders
11.0  Skin and subcutaneous tissue disorders
 8.1  Musculoskeletal, connective tissue and bone disorders
 4.7  Renal and urinary disorders
 2.8  Pregnancy, puerperium and perinatal conditions
10.4  Reproductive system and breast disorders
 6.2  Congenital and familial/genetic disorders
 9.3  General disorders and administration site conditions
15.7  Investigations
 9.1  Injury and poisoning
 8.8  Surgical and medical procedures
 5.3  Social circumstances
;
run;
/*proc print; run;*/

proc sort data=dot out=dot_Sort;
  by descending pct;
run;

ods graphics / reset width=5in height=3in imagename='Dot_SOC_SAS_AxisTable';
proc sgplot data=dot_sort noborder;
  dropline y=classification x=pct / dropto=y;
  scatter y=classification x=pct / markerattrs=(symbol=circlefilled);
  yaxistable classification pct / location=outside  position=left pad=10 
             valuejustify=right valueattrs=(size=7) labelattrs=(size=8);
  xaxis min=0 grid offsetmin=0 label='Relative Frequency of an Event';
  yaxis fitpolicy=none valueattrs=(size=7) reverse display=none;
run;