%let gpath='C:\';
%let dpi=200;
ods html close;
ods listing gpath=&gpath image_dpi=&dpi;

%include 'C:\BezierMacro.sas';

data Trt;
  do Trt='A', 'B', 'C';
  offset=5*ranuni(3);
    do x=1 to 10;
	  y=offset+5*ranuni(6); output;
	end;
  end;
run;

data Noodles;
  length Noodle $12;
  do Noodle='Jirou Mien', 'Jurou Mien', 'Nuorou Mien';
  offset=5*ranuni(3);
    do x=1 to 5;
	  y=offset+5*ranuni(2); output;
	end;
  end;
run;
proc print data=Noodles;run;

data attrmap;
  length value $12;
  id='Noodle'; 
  value='Jirou Mien'; linestyle='graphdata1'; output;
  value='Jurou Mien'; linestyle='graphdata2'; output;
  value='Nuorou Mien'; linestyle='graphdata4'; output;
  id='Trt'; 
  value='A'; linestyle='graphdata1'; output;
  value='B'; linestyle='graphdata2'; output;
  value='C'; linestyle='graphdata3'; output;
run;
proc print data=attrmap;run;

/*--Series--*/
ods graphics / reset attrpriority=color width=5in height=3in imagename="Series";
title "How do you like your Noodles? - Dry";
proc sgplot data=Noodles dattrmap=attrmap noautolegend;
  series x=x y=y / group=Noodle transparency=0.5 
         lineattrs=(thickness=20) attrid=Noodle name='b' curvelabel curvelabelattrs=(weight=bold);
  xaxis display=none;
  yaxis display=none;
  run;

/*--Series Smooth Connect--*/
ods graphics / reset attrpriority=color width=5in height=3in imagename="SeriesSmooth";
title "How do you like your Noodles? - Moist";
proc sgplot data=Noodles dattrmap=attrmap noautolegend;
  series x=x y=y / group=Noodle transparency=0.5 smoothconnect
         lineattrs=(thickness=20) attrid=Noodle name='b' curvelabel curvelabelattrs=(weight=bold);
  xaxis display=none;
  yaxis display=none;
  run;

/*--Wet Noodles--*/
%let n=20;
%BezierMacro (data=Noodles, x=x, y=y, group=Noodle, out=NoodleBez, outx=xbe, outy=ybe, outg=Noodle, n=&n);
proc print data=NoodleBez;run;

ods graphics / reset attrpriority=color width=5in height=3in imagename="Noodle_Graph_5_&N";
title "How do you like your Noodles? - Wet";
footnote j=l "Spline Segments = &n";
proc sgplot data=NoodleBez dattrmap=attrmap noautolegend;
  series x=xbe y=ybe / group=Noodle transparency=0.5 
         lineattrs=(thickness=20) attrid=Noodle name='b' curvelabel curvelabelattrs=(weight=bold);
  xaxis display=none;
  yaxis display=none;
  run;

/*--Treatment Curves--*/
%let n=20;
%BezierMacro (data=Trt, x=x, y=y, group=trt, out=TrtBez, outx=xbe, outy=ybe, outg=gbe, n=&n);

ods graphics / reset attrpriority=color width=5in height=3in imagename="Noodle_Graph_10_&N";
title "Some Response Curves by Treatment";
footnote j=l "Spline Segments = &n";
proc sgplot data=TrtBez dattrmap=attrmap;
  series x=xbe y=ybe / group=gbe transparency=0.5 
         lineattrs=(thickness=8) attrid=Trt name='b';
  keylegend 'b' / title='Treatment: ' location=inside position=bottomleft linelength=20 autoitemsize;
  xaxis display=none;
  yaxis display=none;
  run;

title;
footnote;