data confidence;
input Var $ 1-2 Mean  LowerCI UpperCI;
datalines;
X1      1.2     0.1     4.2
X2      1.2     0.1     4.2
X3      50.0    48.7    60.3
X4      6.0     5.0     7.3
X5      6.1     5.0     7.3
X6      16.7    0.4     64.1
X7      66.4    55.2    69.6
;
run;

proc template;
  define statgraph confidence_V;
    begingraph;
      entrytitle 'Mean and Confidence Intervals';
      layout overlay / yaxisopts=(griddisplay=on);
	    barchartparm x=var y=mean / errorupper=upperci errorlower=lowerci;
	  endlayout;
	endgraph;
  end;
run;

ods listing;
ods graphics / reset width=500px height=300px imagename='confidence_GTL_V';
proc sgrender data=confidence template=confidence_V;
run;

proc template;
  define statgraph confidence_H;
    begingraph;
      entrytitle 'Mean and Confidence Intervals';
      layout overlay / xaxisopts=(griddisplay=on);
	    barchartparm x=var y=mean / orient=horizontal errorupper=upperci errorlower=lowerci;
	  endlayout;
	endgraph;
  end;
run;


ods graphics / reset width=500px height=300px imagename='confidence_Dot_SG';
title 'Mean and Confidence Intervals';
proc sgplot data=confidence;
  scatter y=var x=mean / xerrorlower=lowerci xerrorupper=upperci 
          markerattrs=(symbol=circlefilled size=9);
  run;